Agenda slides

If you have ever run a conference or meeting where many speakers have PowerPoint presentations you will know it can be a nightmare. Often speakers have little idea of how to start their presentation.

Creating a one slide presentation with links to each presentation is a great idea but is a hassle to set up especially if you're short of time.

This simple vba can do it for you. First place all the presentations in a folder. It will help if they have descriptive names!  Open the vb editor and add a module (read this if you don't know how) and then add the code below:

Note this code relies on the presentations being in a folder called 'Files' on your desktop but is easily altered

'copy from here
Sub makeagenda()
'© Technology Trish Ltd 2008
Dim strFolder As String
Dim strSpec1 As String
Dim strName As String
Dim oTarget As Presentation

' Edit this if necessary:
strFolder = Environ("USERPROFILE") & "\Desktop\Files\"
strSpec1 = "*.PP*" ' includes ppt,pptx,pps,ppsx
Set oTarget = ActivePresentation
oTarget.Slides.Add 1, ppLayoutText
oTarget.Slides(1).Shapes(1).TextFrame.TextRange = "Menu"
strName = Dir$(strFolder & strSpec1)
While strName <> ""
With oTarget.Slides(1).Shapes(2).TextFrame.TextRange
With .Lines(.Lines.Count + 1)
.Text = strName & vbCrLf
.Font.Size = 14
With .ActionSettings(ppMouseClick)
.Action = ppActionHyperlink
.Hyperlink.Address = strFolder & strName
End With
End With
End With
strName = Dir()
Wend
End Sub 'to here

If you were looking to put the Summary Slide tool back in 2007 see here

Make sure that the one slide presentation is the Active Window and run the macro

Instant Agenda!

Back to the Index Page

POWERPOINT BLOG

Articles on your favourite sport

Free Microsoft PowerPoint Advice, help and tutorials, Template Links
This website is sponsored by Technology Trish Ltd
© Technology Trish 2007
Registered in England and Wales No.5780175
PowerPoint® is a registered trademark of the Microsoft Corporation